Dłuuuugo zastanawiałam się, co napisać w związku z gorącym ostatnio tematem, jakim jest nagły wzrost kursu franka (długo też pisałam ten artykuł). Miałam dwa pomysły: (1) Jak bardzo wzrośnie rata kredytu w przeliczeniu na złotówki; (2) Czy w ogóle opłacało się brać kredyt we frankach? Pierwszy temat wydał mi się zbyt prosty jak na artykuł, a drugi jakoś zupełnie mi nie leżał. Teraz podwójnie się cieszę, że nie podjęłam tego tematu, ponieważ napisał już o tym Michał Szafrański – autor blogu Jak oszczędzać pieniądze. Artykuł świetny, naprawdę warto przeczytać.

O czym więc będzie ten wpis? Stwierdziłam, że przeszłości i tak już nie zmienimy – co się stało, to się nie odstanie, więc trzeba się zastanowić, co TERAZ możemy zrobić? I znów – Michał Szafrański napisał już artykuł na ten temat (również polecam!). Ja natomiast poruszę temat, o którym słyszę bardzo często, mianowicie przewalutowanie kredytu. Dużo osób, z którymi rozmawiam, myśli właśnie o takiej formie uwolnienia się od wysokiego kursu franka. Czy jednak rzeczywiście się od niego uwolni? Czy przewalutowanie się opłaca? W tym artykule przedstawię narzędzie (stworzone przy merytorycznej pomocy kolegi, który pracuje w bankowości), które może pomóc Wam podjąć decyjzę.

W artykule opisałam poszczególne kroki tworzenia kalkulatora, a sam kalkulator dodałam jako załącznik. Zaczynajmy!

Dodatkowo chcę, abyście wiedzieli, że poniższy artykuł przedstawia narzędzie, które porównuje prognozowane koszty kredytów: w CHF oraz przewalutowanego na PLN. Pamiętajcie też, że dane w nim zawarte to tylko prognozy, a nie przepowiadanie przyszłości. Jej nikt przecież nie zna, tak samo jak przyszłych stawek stóp procentowych i kursów walut. Jeśli więc macie swoje propozycje tych wartości – wpiszcie je samodzielnie. Decyzję o przewalutowaniu podejmijcie samodzielnie (nie ponoszę za nią odpowiedzialności).

Do czego służy kalkulator?

Kalkulator porównuje prognozowane koszty kredytów w CHF i przewalutowanego na PLN . Ponieważ jest to jedynie narzędzie, to dane waszych kredytów, wszelkie prognozy stóp procentowych i kursów walut należy wpisać samodzielnie (w pliku znajdują się przykładowe wartości). Po uzupełnieniu tych danych w arkuszu rozpisane zostaną szczegółowo dwa kredyty: w CHF i w PLN. Utworzy się również porównanie kredytów: kwota do spłaty i informacje o wysokości rat – średniej, największej i najmniejszej.

Dla obu kredytów jest możliwość podania LIBOR-u, WIBOR-u i kursu CHF dla każdej raty. Ponieważ przyszłości nikt nie zna, obecnie w arkuszu znajdują się stawki losowe (nie ponoszę za nie odpowiedzialności). Przypominam również, że najlepiej będzie, gdy wpiszecie własne propozycje tych wskaźników.

Założenia

Ważne, abyście znali założenia, jakie mi przyświecały, gdy tworzyłam ten kalkulator. Oto one:

1. Należy samodzielnie wpisać wartości liczbowe dotyczące kredytów.
2. Plik daje możliwość ustalenia zmiennych stóp procentowych i zmiennego kursu CHF (można je wpisać samodzielnie). Można również ustalić stałą wartość każdego z tych wskaźników dla wszystkich rat.
3. Kalkulator liczy koszty kredytu związane z terminowym spłacaniem rat (wszelkie koszty dodatkowe i odstępstwa od harmonogramu spłat, np. wcześniejsza spłata, nie są brane pod uwagę).
4. Wyliczane są raty równe (stałe).
5. Kredyty porównywane są w tym samym przedziale czasowym, czyli „Co by było gdyby przewalutować kredyt na PLN, a co – gdyby dalej płacić kredyt w CHF?”.
6. Raty płacone są co miesiąc.

Każdy kredyt rozpisałam na raty, w których wyodrębniłam część kapitałową i odsetkową. Dzięki temu będziecie mogli zobaczyć, ile macie do spłaty kapitału (i jak on rośnie w przypadku franków), a ile – odsetek.

Budowa pliku

Plik składa się z 3 arkuszy:

1. Liczba rat,
2. Przewalutowanie,
3. Nowa rata.

Liczba rat służy do określenia, ile rat kredytu w CHF już zapłaciliśmy, a ile nam jeszcze zostało. Wyliczona liczba przyszłych rat jest następnie wykorzystywana do rozpisania hipotetycznego harmonogramu kredytu. Tak wygląda formatka z przykładowymi danymi:

Formatka do ustalania liczby rat

Arkusz Przewalutowanie to właściwy kalkulator. Należy w nim uzupełnić wszystkie dane kredytów: w CHF i przewalutowanego na PLN. Te dane to:

• pozostały do spłaty kapitał w CHF,
• marże banków,
• prognozowane stawki LIBOR-u i WIBOR-u,
• prognozowany kurs CHF do obliczania rat,
• kurs CHF do przewalutowania kredytu.

Zarówno stawki referencyjne (LIBOR, WIBOR), jak i prognozowany kurs CHF można ustalić na stałym poziomie dla wszystkich rat lub mogą być one inne dla każdej raty. Decyzję o tym, co lepsze, zostawiam wam. A tak wygląda ten arkusz (w sporym pomniejszeniu, żeby się zmieścił na ekranie):

Formatka kalkulatora

I w końcu obliczanie raty. Pomyślałam, że na pewno każdy z was będzie chciał wiedzieć, jak wysoką ratę ma do zapłacenia. Możecie to bardzo łatwo obliczyć w arkuszu Nowa rata. Jedyne, co trzeba w nim uzupełnić, to wysokość raty w CHF i aktualny kurs CHF. Formatka wygląda tak:

Formatka do obliczania nowej raty

Przejdę teraz do opisywania formuł, jakie znajdują się w poszczególnych komórkach.

Tworzenie pliku

Jak już stworzyliście i nazwaliście 3 arkusze tak, jak opisywałam powyżej, możemy przejść do formuł, które znajdują się w poszczególnych arkuszach. Będę opisywała je po kolei. Zacznę od wyliczenia liczby rat.

Arkusz Liczba rat

Najpierw stwórzmy formatkę. Powinna ona wyglądać tak, jak na tym obrazku:

Formatka do liczenia liczby rat

Danymi, które będziemy wpisywać są:

• liczba lat kredytowania (komórka E7),
• data pierwszej raty (E8),
• dzisiejsza data (E9).

Ważne, aby dzisiejsza data była datą przed ewentualnym przewalutowaniem kredytu. Inaczej mówiąc – przed zapłaceniem kolejnej raty kredytu w CHF, a tym samym – pierwszej raty kredytu w PLN. Komórki do wpisywania zaznaczyłam na żółto. Przykładowe dane widzimy na rysunku powyżej.

Z kolei wartościami wyliczanymi będą:

• liczba wszystkich rat (E10),
• liczba zapłaconych już rat (E12),
• liczba rat do spłaty (E13).

W moim przykładzie kredyt w CHF zaciągnięto 2 stycznia 2006 r. na 30 lat. Do 1 lutego 2015 r. zapłacono więc 108 rat, a do spłaty pozostały 252 raty.

Do wyliczenia wszystkich rat należy posłużyć się taką formułą (komórka E10):

=E7*12

Liczbę zapłaconych rat można wyliczyć następująco (E11):

=(ROK(E9)-ROK(E8))*12+MIESIĄC(E9)-MIESIĄC(E8)+JEŻELI(DZIEŃ(E9)>=DZIEŃ(E8);0;-1)

Formuła wygląda kosmicznie, wiem. 🙂 Liczy liczbę lat, jaka minęła między dwiema datami, i mnoży ją przez 12 (chcemy poznać liczbę miesięcy). Do tego dodaje liczbę miesięcy, którą liczy jako różnicę między miesiącem nowego a starego roku – jeśli liczba wyjdzie ujemna, to oczywiście ją odejmie. Jest to ok, dlatego, że wcześniej więcej miesięcy załapało się do różnicy lat. I w końcu jeśli dzień bieżącego miesiąca jest większy lub równy dniu początkowego miesiąca to dodaje jeszcze jeden, a jak nie jest – nie dodaje nic (pełen miesiąc jeszcze nie minął).

Liczba rat do spłaty to prościutka formuła odejmująca liczbę zapłaconych rat od liczby wszystkich rat do spłaty (E13):

=E10-E12

Właśnie ta wartość interesuje nas najbardziej, gdyż będzie to liczba rat, w jakiej będzie spłacany kredyt w PLN. O tym dowiemy się z następnego arkusza.

Arkusz Przewalutowanie

W tym arkuszu przyjmiemy założenia (dane) dla kredytów, rozpiszemy każdy z nich na raty, a na koniec stworzymy podsumowanie, czyli podstawę do odpowiedzi na pytanie, co się bardziej opłaca. Będzie trochę wypełniania, ale nie przerażajcie się! Zaczynamy od założeń dla kredytów.

Formatki do wpisania założeń wyglądają następująco (na obrazku widać przykładowe dane):

Formatki do założeń kredytów

Żółte i niebieskie pola należy uzupełnić samodzielnie:

• pozostały do spłaty kapitał w CHF (komórka E7),
• marże banków (E8 i F8),
• prognozowany LIBOR* i WIBOR* (E9 i F9),
• prognozowany kurs CHF* (F14),
• kurs franka użyty do przewalutowania (F15).

Dane oznaczone wyżej gwiazdką (*) są prognozowane i na potrzeby symulacji stałe dla wszystkich rat. Arkusz stworzymy w ten sposób, aby były one wykorzystywane do wyliczania wszystkich rat (odpowiednio w CHF i PLN). Będzie można oczywiście ustalić te wartości dla każdej raty oddzielnie. po prostu nie skorzystamy ze zdefiniowanych wyżej wartości.

Wysokość kredytu w PLN obliczamy następującą formułą (komórka F7):

=ZAOKR(E7*F15;2)

Pozostała liczba rat zarówno w kredycie w CHF, jak i w PLN, to oczywiście wynik przeniesiony z komórki E13 arkusza Liczba rat. W komórkach E10 i F10 należy więc wpisać:

='Liczba rat'!E13

Kredyt w CHF

Przejdźmy zatem do obliczania wysokości rat kredytu w CHF. Najpierw stwórzmy formatkę:

Formatka dla kredytu w CHF

Pokażę teraz po kolei formuły służące do wyliczenia poszczególnych rat. Wszystkie te formuły należy skopiować aż do wiersza 381 (zakładam, że kredyt bierzemy na maksymalnie 30 lat, czyli 360 rat).

Formuła licząca numer raty (Nr) wygląda następująco (komórka B22):

=JEŻELI(A22<='Liczba rat'!$E$13;Przewalutowanie!A22;"")

Formuła, którą należy wpisać w pierwszej komórce kolumny Data (C22), to:

='Liczba rat'!E9

Natomiast w pozostałych komórkach tej kolumny (C23 i dalej), formuła jest już nieco bardziej skomplikowana (skopiuj ją do końca):

=JEŻELI(B23<>"";DATA(ROK(C22);MIESIĄC(C22)+1;DZIEŃ(C22));"")

Formuła dla LIBOR-u (D22):

=JEŻELI(B22<>"";$E$9;"")

Przypominam, że powyższa formuła umożliwia wpisanie stałego LIBOR-u dla wszystkich rat. Jeśli chcesz symulować LIBOR dla każdej raty oddzielnie (a raczej dla każdych 3 rat), to – zamiast pisać tę formułę – wpisz wartość ręcznie.

Dla kursu CHF sytuacja z formułą jest identyczna jak dla LIBOR-u. Oto formuła w komórce E22:

=JEŻELI(C22<>"";$F$14;"")

Formuła w pierwszej komórce kapitału w CHF pozostałego do spłaty (F22) to:

=E7

A dla kolejnych komórek (od F23 w dół):

=JEŻELI(C23<>"";F22-G22;"")

Formuła dla części kapitałowej raty w CHF (Kapitał, G22) wykorzystuje funkcję finansową PPMT:

=JEŻELI(C22<>"";-PPMT(($E$8+D22)/12;1;$E$10-B22+1;F22);"")

Z kolei formuła dla części odsetkowej raty w CHF (H22) wykorzystuje funkcję IPMT:

=JEŻELI(C22<>"";-IPMT(($E$8+D22)/12;1;$E$10-B22+1;F22);"")

Zwróć uwagę, że zarówno przed funkcją PPMT, jak i IPMT postawiłam znak minus („-„). Zrobiłam tak dlatego, że w innym przypadku funkcja zwróciłaby wartość ujemną, a mnie zależy na dodatniej.

Następna jest formuła dla raty w CHF (I22):

=JEŻELI(C22<>"";SUMA(G22:H22);"")

Oczywiście wysokość raty można również obliczyć funkcją PMT, jednak da ona ten sam wynik, co zaproponowane przeze mnie sumowanie.

Teraz zajmę się obliczaniem wartości związanych z ratą, ale w przeliczeniu na złotówki. Każdą wartość (część odsetkową, kapitałową i całą ratę) przeliczę na złotówki. Formuła dla części kapitałowej w racie (Kapitał) w PLN (J22) jest taka:

=JEŻELI(B22<>"";G22*$E22;"")

Dla części odsetkowej w PLN (K22):

=JEŻELI(B22<>"";H22*$E22;"")

Formuła dla całej raty w PLN (L22):

=JEŻELI(C22<>"";ZAOKR(I22*E22;2);"")

Na koniec dodam formuły sumujące wszystkie opisane wyżej wartości. Aby to zrobić, należy zaznaczyć komórki G19:L19 i wpisać taką formułę:

=SUMA(G22:G381)

Następnie należy zatwierdzić kombinacją klawiszy Ctrl + Enter (więcej o tym przydatnym skrócie klawiszowym znajdziesz tutaj: Szybkie wprowadzanie formuł z zachowaniem formatowania).

Ufff. To tyle jeśli chodzi o kredyt w CHF. Przejdę teraz do kredytu w PLN, przy którym będzie mniej pracy. 🙂

Kredyt w PLN

Tradycyjnie na początku pokazuję formatkę:

Formatka dla kredytu w PLN

Formuła dla numeru raty (N22) to po prostu wskazanie odpowiedniego numeru raty kredytu walutowego:

=B22

Formuła dla WIBOR-u (O22) też jest prosta, jednak z tym samym zastrzeżeniem co dla LIBOR-u:

=JEŻELI(N22<>"";$F$9;"")

Formuła dla pozostałego do spłaty kapitału w PLN jest następująca dla pierwszej komórki (P22):

=F7

A dla kolejnych (P23 w dół):

=JEŻELI(N23<>"";P22-Q22;"")

Analogicznie do kredytu w CHF dwie kolejne formuły będą używały funkcji finansowych. Formuła dla części kapitałowej w racie (Kapitał) w PLN (Q22):

=JEŻELI(N22<>"";-PPMT(($F$8+O22)/12;1;$F$10-N22+1;P22);"")

I formuła dla części odsetkowej w PLN (R22):

=JEŻELI(N22<>"";-IPMT(($F$8+O22)/12;1;$F$10-N22+1;P22);"")

Na koniec zaś formuła sumująca ratę w PLN (S22):

=JEŻELI(N22<>"";SUMA(Q22:R22);"")

Nie musimy nic przeliczać na inną walutę, więc na tym kończymy.

Porównanie kredytów

No właśnie. Który kredyt lepszy? Kontynuować spłacanie zadłużenia w CHF, czy przerzucić się na PLN? Stwórzmy porównanie. Oto formatka:

Formatka do porównania kredytów

A formuły podam niestandardowo w tabelce. Uznałam, że tak będzie najłatwiej pokazać, jaka formuła gdzie się znajduje:

Formuły porównujące kredyty

I jak? Który kredyt się bardziej opłaca? 🙂

Arkusz Nowa rata

O tym będzie krótko. Obliczanie raty, jaką powinniśmy zapłacić w danym miesiącu, wyliczymy, mnożąc obecny kurs franka (D5) przez wysokość raty we frankach (D6). Formatka do wyliczenia wygląda tak:

Formatka do obliczania nowej raty

Zatem w komórce D8 należy wpisać następującą formułę:

=ZAOKR(D6*D5;2)

Zaokrąglamy oczywiście do groszy, czyli do dwóch miejsc po przecinku. I tyle!

Komu jeszcze może przydać plik?

Temat kredytów we franku jest teraz gorący. Jeśli dotyczy Ciebie, to mam nadzieję, że tym artykułem pomogłam Ci w decyzji dotyczącej ewentualnego przewalutowania. Jeśli nie masz kredytu walutowego, to ufam, że przynajmniej poznasz ciekawe funkcje finansowe. 😉

Jeśli znasz kogoś, kto (też) spłaca kredyt we frakach, możesz wysłać mu plik lub link do tego artykułu. Zależy mi na tym, aby skorzystało z niego jak najwięcej osób.

Redakcja językowa: Aleksandra Wasiak