• Zapisz się do newslettera, aby otrzymywać powiadomienia o nowościach na blogu
    Zapisując się, wyrażasz zgodę na przesyłanie Ci informacji o nowościach na tym blogu. Zgodę możesz w każdej chwili wycofać (szczegóły).

Jak zaokrąglić czas pracy w górę do 15 minut?

Czyli czas pracy tłumacza

Jakiś czas temu napisał do mnie czytelnik z prośbą o napisanie formuły, która będzie liczyła czas pracy tłumacza na takich zasadach:

  • czas pracy zaokrąglany w górę do pełnych 15 minut,
  • minimalny czas rozliczenia: 1 godzina

Pracujemy na takich danych, jak na obrazku i chcemy określić jakie wynagrodzenie należy się tłumaczowi za konkretne tłumaczenie:

Formatka

W tym wpisie pokażę Ci 2 sposoby na obliczenie wynagrodzenia. Pierwszy będzie zaokrąglał czas pracy. Drugi – będzie zaokrąglał wynagrodzenie.

Szukasz szkolenia z Excela dla HR?

Mogę je dla Ciebie poprowadzić tradycyjnie lub on-line

Najbliższy termin: 21-22 lipca 2020
Zobacz szczegóły

Obliczanie czasu pracy

To będzie prosta sprawa – po prostu odejmiemy czas początkowy od czasu końcowego. Moje dane znajdują się w obiekcie tabela, więc skorzystam z odwołań strukturalnych, aby utworzyć formuły. Jeśli Ty zaś, drogi czytelniku, wolisz tradycyjne odwołania – możesz takich użyć, po prostu wpisz je ręcznie. Efekt będzie ten sam.

Formuła w kolumnie Czas pracy wygląda następująco:

=[@[Godzina do]]-[@[Godzina od]]

Jeśli chcesz użyć tradycyjnych odwołań, to formuła będzie analogiczna:

=D4-C4

A to efekt:

Obliczony czas pracy

Zaokrąglanie czasu pracy w górę do 15 minut

Kolejnym krokiem jest zaokrąglenie obliczonego czasu w górę do pełnych 15 minut, zgodnie z założeniami.

Chodzi tutaj o to, że jeśli pracownik będzie pracował 1 godzinę i 3 minuty – ma zostać mu naliczona 1 godzina i 15 minut.

Jeśli pracował 1 godzinę i 13 minut – również ma zostać naliczona 1 godzina i 15 minut.

Do takiego zaokrąglenia użyję funkcji ZAOKR.W.GÓRĘ.MATEMATYCZNE. Jest to funkcja niedostępna w starszych wersjach Excela. W nich możesz użyć funkcji ZAOKR.W.GÓRĘ. Obie funkcje nadają się tutaj równie dobrze.

Formuła w kolumnie Czas ZAOKRąglony wygląda więc tak:

=ZAOKR.W.GÓRĘ.MATEMATYCZNE([@[Czas pracy]];"00:15")

W powyższej formule, w drugim argumencie, istotność, podałam w formie tekstowej czas, do jakiego ma zostać zaokrąglony czas pracy. Lubię ten sposób, ponieważ jest bardzo czytelny.

Można również odwołać się do komórki, która zawiera wpis o 15 minutach, albo go wyliczyć bezpośrednio w formule, o tak:

=ZAOKR.W.GÓRĘ.MATEMATYCZNE([@[Czas pracy]];15/60/24)

Na nasze potrzeby efekt będzie ten sam: uzyskamy zaokrąglony w górę czas pracy. To spełnia pierwsze nasze założenie. Teraz czas na drugie.

Uwzględnianie minimalnego czasu rozliczenia: 1 godzina

Drugie założenie mówi, że minimalny czas rozliczenia tłumaczenia to 1 godzina. Czyli nawet, jeśli tłumacz pracuje np. tylko 13 minut – wynagrodzenie otrzyma za pełną godzinę. Dotyczy to tylko pierwszej godziny, pozostałe rozliczamy już zaokrąglając w górę do 15 minut (czyli poprzedni podrozdział artykułu).

Tylko jak to teraz wcisnąć w formułę?

Zrobię to tak, że powiem Excelowi, aby z dwóch wartości:

  1. wyliczonego przed chwilą czasu pracy,
  2. 1 godziną

wybrał tę większą. Jeśli więc tłumacz będzie pracował 13 minut – Excel wybierze 1 godzinę.  Jeśli tłumacz będzie pracował 1 godzinę i 17 minut – wybierze 1 godzinę i 17 minut. Użyję do tego funkcji MAX (ona umie wybierać największą wartość). Żeby tylko jeszcze zachować nasze zaokrąglenie – umieszczę MAX w formule, którą wcześniej napisałam. O tak:

=MAX(ZAOKR.W.GÓRĘ.MATEMATYCZNE([@[Czas pracy]];"00:15");1/24)

Godzinę zapisałam jako 1/24.

Efekt mamy taki:

Obliczony czas pracy zaokrąglony

 

Wyliczanie wynagrodzenia – sposób 1

Teraz została nam już najprostsza czynność, czyli wyliczenie wynagrodzenia na podstawie zaokrąglonego czasu pracy. O tym już kiedyś pisałam, teraz tego użyję.

Formuła w kolumnie Wynagrodzenie wygląda tak:

=[@[Czas ZAOKRąglony]]*[@[Stawka/h]]*24

I tyle. Wszystko. Efekt mamy taki:

Obliczone wynagrodzenie

Zaprezentowana metoda mi się bardzo podoba, dlatego, że użycie kolumny pomocniczej, wyliczającej zaokrąglony czas, pozwala łatwo ustalić za ile czasu faktycznie tłumacz zostanie wynagrodzony. Ja bym użyła właśnie tego rozwiązania.

Ale może być też inne…

Wyliczanie wynagrodzenia – sposób 2

To rozwiązanie nie potrzebuje kolumny pomocniczej, wyliczający zaokrąglony czas, ponieważ tutaj będziemy zaokrąglać wynagrodzenie. Funkcje będą te same, co w sposobie 1.

Wynagrodzenie za 15 minut pracy wynosi 100/4=25 zł (4=60/15). Czyli jeśli zaokrąglamy czas w górę do 15 minut, to jest to to samo, co zaokrąglenie wynagrodzenia do 25 zł. Oczywiście nadal nie możemy wypłacić mniej niż 100 zł, czyli za godzinę pracy.

Proponuję więc taką formułę:

=ZAOKR.W.GÓRĘ.MATEMATYCZNE(MAX(1/24;[@[Czas pracy]])*24*[@[Stawka/h]];[@[Stawka/h]]/4)

Zauważ, że tutaj, funkcja ZAOKR.W.GÓRĘ.MATEMATYCZNE zaokrągla wyliczone wynagrodzenie do 25 zł. Nadal wewnątrz funkcji sprawdzamy, czy czas pracy nie jest mniejszy niż godzina. Możemy też sprawdzić, czy wypłacone wynagrodzenie nie jest mniejsze niż 100 zł – wyjdzie na to samo:

=MAX([@[Stawka/h]];ZAOKR.W.GÓRĘ.MATEMATYCZNE([@[Czas pracy]]*24*[@[Stawka/h]];[@[Stawka/h]]/4))

Efekt uzyskujemy taki (kolumna Wynagrodzenie2):

Metoda 2 – wynik

I wszystko :). Mam nadzieję, że Ci się to przyda :).

Powiązane produkty

  • O obiekcie tabela słów kilka – podczas tej lekcji pokazuję czym jest obiekt tabela w Excelu i dlaczego warto z niego korzystać. Daje nam on ogromne możliwości dynamizowania naszych arkuszy, a wiele nowych funkcjonalności Excela wręcz wymaga przechowywanie danych w tymże obiekcie (np. Power Query). Must have każdego użytkownika Excela!
  • Kurs Excel w codziennej pracy – mający na celu uporządkować Twoją wiedzę na temat Excela. Jest świetny zarówno dla osób, które chcą uporządkować swoją wiedzę, zdobywaną do tej pory “po omacku”, jak i takich, które dopiero zaczynają swoją przygodę z Excelem.

 

Plik do pobrania:

MalinowyExcel Czas pracy zaokrąglenie do 15 minut dw.xlsx

 

I film na Youtubie, gdzie pokazuję powyższe rozwiązanie:

 

 

 

 

Spodobał Ci się ten artykuł?

Jeśli TAK, zapisz się na newsletter, aby otrzymywać powiadomienia
o o nowościach na blogu.

Zapisując się, wyrażasz zgodę na przesyłanie Ci informacji o nowościach na tym blogu. Zgodę możesz w każdej chwili wycofać (szczegóły).

Tagi , , , , , , , , , , , , .Dodaj do zakładek Link.

Dodaj komentarz

Twój adres email nie zostanie opublikowany. Pola, których wypełnienie jest wymagane, są oznaczone symbolem *